Beranda
ITShare

Cara Mudah Kustomisasi Terminal Fedora: Lebih Keren dan Produktif

LATAR BELAKANG

Terminal di Linux sering dianggap “membosankan” karena tampilannya polos, hanya teks hitam putih. Padahal, dengan sedikit sentuhan, terminal bisa menjadi lebih informatif dan nyaman dipakai sehari-hari. Tampilan baru yang menampilkan logo direktori, status Git repository, branch aktif, hingga posisi command yang rapi di bawah prompt akan membuat pengalaman bekerja di terminal terasa profesional sekaligus menyenangkan.

PEMBAHASAN

  1. Instalasi Fish Shell
    Fish adalah alternatif shell yang lebih interaktif dibanding Bash. Ia mendukung auto-complete, syntax highlighting, dan reminder command yang sangat membantu ketika kita sering mengetik perintah berulang. 
    sudo dnf install fish -y
  2. Menambahkan Nerd Fonts
    Agar ikon-ikon di prompt tampil sempurna, kita perlu font khusus. Unduh dari repo resmi:
    Github Nerd Font
    Ekstrak Fonts di Folder ini 
    ~/.local/share/fonts
  3. Mengubah Style Fish
    Edit file Config dan Tambahkan Kode Berikut
    Lokasi Config 
    ~/.config/fish/config.fish

    if status is-interactive

    #
    # --- Custom prompt_pwd: keep last 4 full directories ---
    #
    function prompt_pwd
        set -l parts (string split / (pwd))
        set -l count (count $parts)

        # If 4 or fewer → show full path
        if test $count -le 4
            echo (pwd)
            return
        end

        # Number of leading directories to shorten
        set -l leading_count (math $count - 4)

        set -l leading ""
        for i in (seq 1 $leading_count)
            set p $parts[$i]
            if test -n "$p"
                set leading $leading"/"(string sub -s 1 -l 1 $p)
            end
        end

        # Last 4 full directories
        set -l tail $parts[(math $count - 3)]"/"$parts[(math $count - 2)]"/"$parts[(math $count - 1)]"/"$parts[$count]

        echo $leading"/"$tail
    end

    #
    # --- Custom fish prompt with icons ---
    #
    function fish_prompt
        # Colors
        set user_color (set_color cyan)
        set host_color (set_color brblue)
        set path_color (set_color yellow)
        set git_color (set_color magenta)
        set arrow_color (set_color green)
        set reset_color (set_color normal)

        # Icons (Nerd Font)
        set icon_user ""
        set icon_host ""
        set icon_folder ""
        set icon_git ""
        set icon_arrow "❯"

        # User + Host
        echo -n "$user_color$icon_user "(whoami)" "
        echo -n "$host_color$icon_host "(hostname)" "

        # Path
        echo -n "$path_color$icon_folder "(prompt_pwd)" "

        # Git (only if inside repo)
        set git (fish_git_prompt)
        if test -n "$git"
            echo -n "$git_color$icon_git $git "
        end

        # Newline + arrow
        echo ""
        echo -n "$arrow_color$icon_arrow $reset_color"
    end
end

# Go environment for fish
set -x GOPATH /mnt/project/go/sdk
set -x PATH $PATH /usr/local/go/bin $GOPATH/bin
  4. Membuat Fish Otomatis Jalan
    Agar membuat fish selalu dijalankan setiap kali masuk terminal, atur pada terminal seperti screenshoot di bawah

    Buka Terminal -> Preferences -> Profile -> Edit
    Terminal Setting

KESIMPULAN

Tanpa framework tambahan, cukup dengan Fish + Nerd Fonts + edit config.fish, terminal Fedora bisa tampil lebih modern:

  • Informasi direktori dan branch Git langsung terlihat.
  • Auto-complete bawaan Fish mempercepat eksekusi command.
  • Fonts Nerd membuat ikon tampil rapi.
Cara sederhana ini sudah cukup untuk membuat terminal lebih informatif dan nyaman dipakai sehari-hari.
Saya seorang programmer dengan fokus developer Web dan Android.